Alabaster — 33 of 123

John Cater, Rob Dubbin, Eric Eve, Elizabeth Heller, Jayzee, Kazuki Mishima, Sarah Morayati, Mark Musante, Emily Short, Adam Thornton, and Ziv Wities

Release 1

Section 2 - Winking

Understand "wink" as winking. [1]

Winking is an action applying to nothing.

Check winking:

if the corpse is knowing:

try winking at the corpse instead;

if the current interlocutor is a person:

try winking at the current interlocutor instead;

otherwise:

say "There's no point, since you're unobserved." instead. [2]

Understand "wink at [someone]" as winking at.

Winking at is an action applying to one thing.

Check winking at the player:

say "You wouldn't really be able to appreciate the gesture, coming from yourself and all." instead.

Carry out winking at someone when Snow White is the current interlocutor: [3]

if the mood of Snow White is weird:

casually queue smirk;

otherwise:

casually queue something-in-your-eye.

Report winking at the corpse when the corpse is not the current interlocutor:

if the corpse is not undead:

say "You wink, but it's unlikely to rouse him." instead;

otherwise:

say "He doesn't move. Maybe you need a more aggressive approach. Maybe you're going mad." instead. [4]

Report winking at the corpse:

say "You wink at [the corpse]. He doesn't respond — if it deserves a response." instead.

Report winking at Snow White:

if the mood of Snow White is:

-- menacing:

say "You wink at [one of]her[or]Snow White[at random].";

-- aggressive:

say "You wink at [one of]her[or]Snow White[at random].";

-- furious:

say "In your experience, winking at infuriated women does not come out well. But you go ahead anyway.";

-- whiny:

say "You wink at [one of]her[or]Snow White[at random], as though she were a small child.";

-- needy:

say "You wink at [one of]her[or]Snow White[at random]. It's meant to say 'hey, don't worry, I'll handle this', but it probably just looks strange..";

-- warm:

say "You wink at [one of]her[or]Snow White[at random].";

-- harmless:

say "You try winking at [one of]her[or]Snow White[at random].";

-- weird:

say "You wink broadly.".

Understand "wink at [body part]" as a mistake ("Your winks aren't so precisely targeted."). [5]

Notes

[1]. Someone tried this because the hart's eye seems to wink early on.

[2]. This should never happen.

[3]. she should see you wink, even if you're not winking at her.

[4]. This should only happen if the hart is in a wakeable-but-not-yet-woken state.

[5]. In case you try winking at the hart's eye. Yeah, it's not that likely.