Alabaster — 65 of 123

John Cater, Rob Dubbin, Eric Eve, Elizabeth Heller, Jayzee, Kazuki Mishima, Sarah Morayati, Mark Musante, Emily Short, Adam Thornton, and Ziv Wities

Release 1

Chapter 1 - The Woods and Scenery

The Dark Woods is a dark room. "It is a moonless night[if stopped-time is happening], though it is hard to pay much attention to the sky when all around you the woods are silenced by magic[otherwise if the player carries the lantern]. The lantern light does not reach far[end if][one of]. You are seldom frightened in these woods, but tonight is unusual[or][stopping]."

The sky is far-off flush scenery in the dark woods. Understand "stars" and "star" and "starlight" and "moon" and "moonlight" and "sun" and "sunlight" or "clouds" or "haze" or "cloud" or "thick haze" as the sky. The description is "The sky is blotted out by pine branches, and even if you could see it, there would be only a few stars out, the rest shrouded by a thick haze. The moon and the sun are looking down on some other part of the world."

Instead of looking under the sky:

say "And what would that signify?"

Some roots are flush scenery in the dark woods. Understand "root" as roots. The description is "You cannot see much at the moment, but they are down there, twisting under the soil, tripping you when you walk."

Instead of looking under the roots:

say "They descend, no doubt, into the soil and then perhaps below they form the ceiling of the land of mines, where the dwarrows are said to work. But you have never seen those wonders, because to have earth over your head is not an idea that pleases you. There will be time enough when you are dead."

Instead of listening to the roots:

say "If you expect to be able to hear them grow, you are disappointed."

Instead of searching the roots:

say "There is nothing there but plant and soil."

Instead of smelling the roots:

say "Ah, damp earth."

Instead of climbing the roots:

say "They would offer significant climbing challenge only to an ant."

Instead of touching or rubbing or squeezing the roots:

say "They are cool and soil-damp."

Instead of taking or pushing or pulling or turning or cutting the roots:

say "You always did find the clearing of land a tedious chore, but it works better if you are at least equipped for the task."

Instead of igniting the roots with the lantern:

say "They are live and well-watered: there's little hope of making them catch."

Instead of tasting or consuming the roots:

say "They're tree roots, not turnips or carrots or beets."

Some trees are scenery in the dark woods. Understand "woods" or "tree" or "forest" or "woods" or "wood" or "foliage" or "leaves" or "leaf" or "branch" or "branches" or "shadows" or "bark" or "pine bark" or "aspen bark" or "around us" or "around me" as trees. The description is "You know the trees in these parts well: a mix of pine and aspen. But all you can see in this light are the ghost-white trunks, and the shadows cast by the pine trees."

After printing the name of the trees while changing the subject:

say " around you"

Some rubs are part of the trees. The description is "Rubs are where the stags wear the velvet from their horns, before season. There would be some if they regularly used this part of the wood; but you caught your hart in an unaccustomed place. Bad luck for him; convenient for you.".

Instead of doing something other than examining when rubs are the noun or rubs are the second noun:

say "This is the wrong part of the forest for any such sign."

Understand "count leaves" or "count the leaves" as a mistake ("Pointless: some are already sodden and disintegrating as autumn ends.").

Instead of inserting something into the trees: [ This will catch THROW FOO INTO WOODS.]

say "You are uncomfortably aware that losing something is not the same as getting rid of it forever. If you want something destroyed, you'll destroy it, but otherwise it is best if everything remains under your control."

Instead of looking under the trees:

say "Some scattered undergrowth grows here and there — less around the base of the pines."

Instead of touching or rubbing or squeezing the trees:

say "The pine bark is rough; the aspen smooth. There are no conspicuous rubs about. You caught this hart outside his normal territory."

Instead of waving or swinging the trees:

say "There is an old wives['] tale of a demoness who used a pine tree for a broom. You, however, are not in her league."

Instead of listening to the trees:

say "When the wind picks up, the trees sigh and rustle. It is a little melancholy, but usual for these parts."

Instead of taking or pushing or pulling or turning or cutting the trees:

say "The harvesting of lumber is a task you gladly leave to [nitwits].";

To say nitwits:

say "[one of]men of less speed and more patience[or]men of less stealth and more strength[or]men of less wit and more bluster[or]your idiot cousins[stopping]"

The undergrowth is scenery in the dark woods. The indefinite article is "some". Understand "bush" or "bushes" or "shrubbery" or "plant" or "ground cover" or "plants" as the undergrowth. The description is "The undergrowth is sparse — pine does not encourage plantlife around its base — but there are bushes here and there nonetheless."

Instead of touching or rubbing or squeezing the undergrowth:

say "There's just too much chance of touching spines or stinging plants that you do not care to go feeling the undergrowth in the dark."

Instead of tying something to the undergrowth:

say "The ground cover is hardly sturdy enough to anchor anything. And in any case the only tying-up that needed to be done this evening has already been accomplished."

Instead of listening to the undergrowth:

say "There is only a very occasional rustle of small animals moving through the plants. They will be able to hear and smell you and Snow White, and see your light, so they are not very daring."

Instead of searching or looking under the undergrowth when the dagger is in the location:

say "Your dagger remains where it fell earlier."

Instead of searching or looking under the undergrowth:

say "There is nothing extraordinary here."

Instead of smelling the undergrowth:

say "It has no special smell other than plant life and rotting leaves and dankness."

Instead of taking or pushing or pulling or turning or cutting the undergrowth:

say "You always did find the clearing of land a tedious chore[one of], but it works better if you are at least equipped for the task[or], and you're happy to leave it to [nitwits][stopping]."

The aspen is scenery in the dark woods. Understand "aspen" or "aspen tree/trees" or "trunk" or "trunks" or "ghost-white trunks" as the aspen. The description is "In daylight, they are beautiful. This time of year the aspen is shedding and the leaves lie deep and golden on the ground."

The pine is scenery in the dark woods. Understand "pines" or "pine trees/tree" as the pine. The description is "They blot out even the little light that might otherwise come from the stars."

Instead of tasting the trees:

say "Sometimes in spring the freshest pine leaf growth is suitable to eat; otherwise, you do not care to test yourself."

Instead of smelling the trees:

say "The dominant scent is that of damp pine needles."

Instead of climbing or entering the trees:

say "These are not good trees for climbing, even with free hands and plenty of light."

Instead of tasting or consuming something inedible:

if the current interlocutor is new-Snow-White:

say "[The noun] won't serve as much of a breakfast — for you or for her. [one of]You both need to get to where you'll be safe and able to eat and sleep[or][stopping].";

otherwise if the player knows vampirism-revealed:

say "You prefer food more suitable for humans. This makes you perhaps unusual in the court. The Queen is always brewing her drugs and tinctures, and [SW-or-Lilith]'s preferences are apparently even more disturbing.";

otherwise:

say "You prefer food more suitable for humans. This makes you perhaps unusual in the court. The Queen is always brewing her drugs and tinctures, and [SW-or-Lilith]... who knows?"

To say SW-or-Lilith:

say "[if the player knows snow-white-possessed]Lilith[otherwise]Snow White[end if]"

Before doing something other than examining when the noun is the pine or the second noun is the pine:

if the noun is the pine, change the noun to the trees;

if the second noun is the pine, change the second noun to the trees;

try the current action instead.

Before doing something other than examining when the noun is the aspen or the second noun is the aspen:

if the noun is the aspen, change the noun to the trees;

if the second noun is the aspen, change the second noun to the trees;

try the current action instead.

Instead of searching the trees:

say "No need: the most frightening thing for miles around is the slip of girl beside you."

Understand "shiver" as a mistake ("You already are.").

Instead of listening to the location, say "[random sound]."

To say random urgency:

say "[one of]You cannot be all night about this[or]You should get back by dawn[or]The Queen may already be wondering where you are[or]The later you get back, the more awful the Queen's questions will be[or]The delay is making you ever less comfortable[stopping]".

To say random lampstate:

say "The lantern [one of]flickers[or]dims[or]brightens again[cycling]"

To say random temperature:

say "[one of]It is getting colder[or]You would be warmer if only you were still moving[or]Your ears are growing numb[or]You stomp your feet to warm them[or]It is so cold that you are barely aware of it any longer[stopping]".

To say random sound:

say "[one of]All around you is silence[or]A breeze stirs the aspens, sending down a few more leaves[or]The branches nearby rustle[or][one of]In the distance, an owl screeches[or]The screech-owl calls again[or]Wings beat in the dark[or]A small animal squeaks: most likely a mouse in the act of being caught by the owl[cycling][or]She shifts her weight, breaking a twig[or]You hear something very far off that sounds like a wolf[as decreasingly likely outcomes]". [1]

Note

[1]. Added the bit about the screech-owl because this animal is associated with Lilith in some Biblical translations. (At least, if Wikipedia is to be trusted.)