Alabaster — 69 of 123

John Cater, Rob Dubbin, Eric Eve, Elizabeth Heller, Jayzee, Kazuki Mishima, Sarah Morayati, Mark Musante, Emily Short, Adam Thornton, and Ziv Wities

Release 1

Chapter 5 - The Corpse

The corpse is an animal in the Dark Woods. The printed name is "decomposing hart corpse". [We've made it animate so that we can address it later, though most of the time this won't go anywhere.] Understand "hart" or "decomposing" or "dead" or "deer" or "animal" or "body" or "beast" or "stag" or "noble" as the corpse. Understand "undead" or "glowing" as the corpse when stopped-time is happening. "[if stopped-time is happening]You are faced, rather uncomfortably, with one undead and glowing hart[otherwise]Earlier, you killed a hart and left it here. It was a preparation: you didn't want to have to hunt such an animal in the darkness[one of].

Now, you can't help wondering whether you should have spared the noble beast[or][stopping][end if]."

Rule for clarifying the parser's choice of the corpse:

do nothing instead.

Before giving or showing something to the corpse when the player does not know hart-thanked or the player knows hart-no-longer-undead:

say "There is, unsurprisingly, no reaction." instead.

The corpse's hair is privately-named. Understand "fur" or "pelt" as the corpse's hair. The printed name of the corpse's hair is "fur". The description is "It is dark and matted with dirt and blood: not a savory thing to look at."

The description of the corpse's eyes is "They are fixed and glassy."

The description of the corpse's nose is "It looks damp and snuffly."

The description of the corpse's chin is "The hart doesn't exactly have a chin in the human sense. Especially not after what the corpse has been through."

The description of the corpse's face is "It was a handsome creature, once. The antlers are still attached."

The description of the corpse's skin is "The skin is mostly still covered with fur."

The description of the corpse's ears is "They are mostly intact — intricate clever structures. You've always admired the ears of animals. Cats, most of all."

The corpse's wrists are privately-named. Understand "hooves" or "hoof" or "leg" or "legs" as the corpse's wrists. The printed name is "hooves". The description is "They are in good condition, and would have left tracks as long as your thumb (you had a look earlier). The hart was perhaps three years old when you killed it."

The description of the corpse's neck is "The neck is the most elegant part of any animal. But seldom useful for much."

The description of the corpse's veins is "The blood will have long since stopped flowing." Understand "hart's" or "neck veins" as the corpse's veins.

The description of the corpse's lips is "Somewhat... frayed."

The description of the corpse's teeth is "They're a bit worn: he's not the youngest buck you've taken."

Instead of cutting or attacking something which is part of the corpse:

if the noun is the hart's heart:

continue the action;

say "You've probably done enough harm already."

Instead of looking under the corpse:

say "There's nothing there but crushed undergrowth."

Instead of smelling the corpse:

say "You know a fine recipe for meat of advanced age: to bury it in cold ground for ten days, then to dig it up again and cut away the green portions, and then to prepare the remainder, stewing in an iron pot, all day long; and then to serve it with nutmegs if they can be gotten, and if not, with strong peppers from the south. It is an extravagant meal, but —

—but in any case the hart has not advanced to such a state as to need such treatment. It could be eaten in the ordinary way, yet, and not make a man ill."

Instead of smelling something which is part of the corpse:

try smelling the corpse.

Instead of attacking the corpse:

if the hart's heart is part of the corpse:

try taking the hart's heart;

otherwise:

say "Haven't you done enough?"

Instead of touching or rubbing or squeezing the corpse:

if the corpse is the current interlocutor:

say "That idea makes you feel ill.";

otherwise if the player knows hart-thanked:

try waking the corpse;

otherwise:

say "You lay a hand on its flank. The flesh is cold."

Instead of pushing or pulling or turning the corpse:

if the corpse is the current interlocutor:

say "It might not appreciate such a gesture.";

otherwise if the player knows hart-thanked:

try saying hello to the corpse;

otherwise:

try taking the corpse.

Instead of waking the corpse:

if the corpse is the current interlocutor:

say "It is already unnervingly awake.";

otherwise if the player knows hart-thanked:

try saying hello to the corpse;

otherwise:

say "You'd need Gabriel's trump: the unfortunate creature is dead."

Instead of taking the corpse:

say "You don't want to encumber yourself with such a large load; you wouldn't be able to move it far, and you have [italic type]her[roman type] to deal with."

Instead of buying the corpse:

say "According to the law of the land, the hart's flesh is already yours, since you were the one who slaughtered him, and were on territory where you have license to hunt[if the corpse is the current interlocutor].

At the moment, however, [the corpse] appears to be exercising squatter's rights[end if]."

Instead of climbing the corpse:

if the corpse is the current interlocutor:

say "What a notion.";

otherwise:

say "It is hardly large enough to provide much scope for climbing."

Instead of consuming or tasting the corpse:

if the corpse is the current interlocutor:

say "Not (you rather think) while it is reanimated and holding a conversation with you.";

otherwise:

say "Not raw, you don't."

Instead of kissing the corpse:

say "Contrary to a certain scurrilous rumor started by your second cousin, you are not attracted to animals of the non-human persuasion."

Instead of waving or swinging the corpse:

say "Even if there were any point in that, it would prove rather bulky."

The hart's heart is part of the corpse. The description of the hart's heart is "It hasn't yet been too much eaten by animals. It should do."

Report dropping the hart's heart:

say "You set [the noun] down carefully where you'll be able to find it again." instead.

Instead of giving or showing the hart's heart to the corpse when the corpse is the current interlocutor:

say "[one of]'I am well aware that you have it,' he says austerely. 'And as it cannot be returned, I suggest we try to pass over the incident with as much tact as possible.'[or]He doesn't seem to want it back himself.[stopping]"

Instead of searching the hart's heart:

say "If you cut it open, it will be ruined for your current purposes."

Instead of wearing the hart's heart:

say "As a trophy, on a string? You're not a man for much jewelry."

Instead of buying something which is part of the corpse:

try buying the corpse.

Instead of buying the hart's heart:

try buying the corpse.

Instead of opening the hart's heart:

say "There will only be blood within."

Instead of smelling the hart's heart:

say "Smells like copper."

Instead of listening to the hart's heart:

say "It is cold and still."

Instead of squeezing or rubbing or touching the hart's heart:

say "You are unable to make it beat again."

Instead of tasting or consuming the hart's heart:

say "Even to taunt your prisoner, you can't bring yourself to take a bite of the raw lump."

Instead of pulling or pushing or turning the hart's heart:

if the hart's heart is part of the corpse:

try taking the hart's heart;

otherwise:

try squeezing the hart's heart.

Instead of searching or looking under the hart's heart when the hart's heart is part of the corpse:

say "It is surrounded by ordinary flesh."

Instead of feeding the hart's heart to Snow White:

if the player knows vampirism-revealed:

say "'Like a bite of heart?' you ask, holding up the one you severed from the stag[first-vampire-accusation]. She pretends not to hear you.";

otherwise:

say "[one of]You hold it up to Snow White's mouth. She looks at it and her lips[set body-context to Snow White] part, but she does not— well, what were you expecting? For her to take a bite out, as though it were a piece of fruit?[or]You have already tried that experiment. It was inconclusive.[stopping]"

Some antlers are part of the corpse. The description is "They are sizable, and firmly attached: this is a deer at the peak of his development, killed in mating season."

Instead of touching or rubbing the antlers:

say "You run your fingers over the antlers for luck."

Instead of searching the antlers:

say "While they might, domesticated, make a suitable rack for hats or cloaks, they are currently unadorned."

Instead of listening to the antlers:

say "Unsurprising silence."

Instead of smelling the antlers:

say "They haven't much scent of their own on this cold night."

Instead of pulling or pushing or turning or taking or cutting or buying the antlers:

if the current interlocutor is the corpse:

say "He would probably take exception to that." instead;

say "[one of]This is no occasion for collecting trophies. Besides, you have three larger sets at home. No: had. Before your cabin was burned by the Queen[cabin-destroyed].

Well, you can collect them another time.[or]You are not currently in the mood for antler-collection.[stopping]"

Instead of squeezing the antlers:

say "They are firm."

The chest cavity is part of the corpse. It is a flush container. The description is "The hart has been only very incompletely butchered. Most of its organs remain intact[if stopped-time is happening]. It is also glowing from the inside, which is not an effect you've ever noticed down at the village butcher shop[end if]." Understand "viscera" or "organs" or "liver" or "guts" or "gut" or "intestine" or "lung" or "lungs" or "kidney" or "stomach" as the chest cavity.

Instead of searching the chest cavity when the hart's heart is part of the corpse:

say "The heart is still partially attached to the body of the corpse."

Instead of inserting something into the chest cavity:

if the noun is the hart's heart:

say "Putting the heart back would not make it work again.";

otherwise if the corpse is the current interlocutor:

say "The woods lack the restrictions of court, but inserting random objects into your interlocutors probably still qualifies as unacceptable.";

otherwise:

say "You have attended many a feast on roast hart, but [the noun] do[es] not constitute suitable stuffing.".

Instead of pulling or pushing or turning or taking or touching or rubbing or squeezing the chest cavity:

say "Being up to your elbow in stag viscera holds no appeal at present."

Instead of looking under or searching the chest cavity:

say "You are not one of those who claim to read the future from the inspection of a creature's organs, but you see nothing to amaze you here."

Instead of cutting or opening the chest cavity:

try cutting the corpse.

Instead of closing the chest cavity:

say "Much, much too late."

Instead of consuming the chest cavity:

try consuming the corpse.

Instead of listening to the chest cavity:

say "What you won't hear is any sort of heartbeat."

Instead of searching the corpse:

try examining the corpse.

The description of the corpse is "[if the hart's heart is part of the corpse]The heart is still there[notice hart's heart] — exposed by your neat cuts, but not damaged yet[otherwise]The heart has been cut out[end if]."

Instead of examining the corpse when the player knows hart-thanked and the player does not know undead-hart:

say "[one of]You peer more closely at it. The heart is gone, the chest cavity lies open, it is plainly dead. And yet it seems to be looking at you with those glassy eyes.[or]Maybe it will speak soon.[or]Perhaps if you touched it it would wake up.[stopping]"

Instead of examining the corpse when the corpse is the current interlocutor:

say "His body still gapes; his fur is still bloody and tattered; but his face is animated by an expression that no animal would have."

Understand "glassy" as the corpse's eyes.

Instead of examining the corpse's eyes when the player knows hart-thanked and the player does not know undead-hart:

say "It winks. Or the lamplight glints off its eyeball. One of those.";

now the corpse is knowing.

The corpse can be knowing or unknowing. The corpse is unknowing. [1]

To say notice (noticed item - an object):

have the parser notice the noticed item. [2]

Understand "extinguish [something]" or "put out [something]" as extinguishing. Extinguishing is an action applying to one thing.

Check extinguishing:

if the noun is not lit:

say "[The noun] cannot be extinguished." instead.

Instead of extinguishing the lantern:

say "Without it, even you will never find your way back to the castle."

Instead of examining yourself:

say "[one of]You haven't slept well in days. And today: the hunt, the death of your dogs, the Queen enraged, the court on edge. An evening of the Queen locked away in her chamber, while the magic mirror talked on and on, its shrieking voice and its laughter audible even if its counsel was not. The uneasy sleep that fell. The more uneasy waking, with the Queen herself in your chamber, bending over your bed. The urgent demand that you take Snow White at once, and bring her here, and end her life.

You are exhausted. Your other feelings are even worse and you do not dare dwell on them.[or]You are so tired and your mind so full of horrible things that you barely know yourself any longer.[stopping]".

Understand "dwell on my feelings" or "dwell on feelings" or "dare to dwell on feelings" or "dare to dwell on my feelings" as a mistake ("Dread; cold; the knowledge of corruption.").

Instead of waiting:

if the nag of the current quip is not "":

stop the action; [3]

otherwise:

say "[beat][line break][paragraph break]".

Notes

[1]. This is so that we can prefer to wink at the corpse if it has seemed to wink at us; but otherwise not.

[2]. This is to deal with the fact that the player may well type "TAKE IT" after being told that the heart is still in the deer's body, even though the pronoun at that point is set to the corpse as a whole.

[3]. In this case, we're already going to have a grounding beat and a comment, so we want beat-comment, not beat-beat-comment, which looks clumsy and in the worst case scenario will give, say, two flickering-lantern messages on a single turn.